윈도우 10, 8 제품 키 없이 확인 하는 방법

윈도우 설치 시 설치과정 또는 윈도우 설치 후 시스템 정보나 도스 명령으로 제품 키를 입력하는데요.
이때 윈도우 레지스트리에 저장됩니다.
입력하고 나서 등록된 제품 키를 확인하려면 프로그램을 다운받아 실행해야 하는데요.
프로그램 다운도 그렇지만 파일 속에 바이러스나 악성코드가 숨어 있을 수도 있습니다.

프로그램 설치 없이 스크립트를 이용해서 레지스트리에 등록된 제품 번호를 알 수 있는데요.

해당 버전은 윈도우 8 이상 10에서 사용할 수 있습니다.

아래 내용을 복사 후 메모장에 붙여넣기 합니다.

복사가 안되는시는 분은 파일을 받아주세요.

윈도우제품키.txt

Option Explicit

Dim shell,path,dId, Result
Set shell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
dId = shell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name : " & shell.RegRead(Path & "ProductName")
ProductID = "Product ID : " & shell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & GetConByKey(dId)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
if vbYes = MsgBox(ProductData & vblf & vblf & "확인 하셨나요?", vbYes + vbQuestion, "윈도우 제품키 확인") then
Save ProductData
End If

'Convert binary to chars
Function GetConByKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
       Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    GetConByKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)


End Function
'Save data to a file
Function Save(Data)
    Dim fso, fileName, txt,shell,userName
    Set shell = CreateObject("wscript.shell")
    'Get current user name
    userName = shell.ExpandEnvironmentStrings("%userName%")
    'Create a text file on desktop
    fileName = "C:\Users\" & userName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fileName)
    txt.Writeline Data
    txt.Close
End Function